Custom Simulations

This is an example of building a custom simulation of a FACS-based screen.

Setup

Lets first start the Julia REPL or a Julia session inside of a Jupyter Notebook and load the packages we'll need:

using Crispulator
using Gadfly

Basic screen parameters

First lets design a simple Crispulator.FacsScreen with 250 genes with 5 guides per gene. Lets say that we make sure we have 1000x as many cells as guides during transfection (representation) and sorting (bottleneck_representation) and 1000x as many reads as guides during sequencing (seq_depth). We'll leave the rest of the values as the defaults and print the object

s = FacsScreen()
s.num_genes = 250
s.coverage = 5
s.representation = 1000
s.bottleneck_representation = 1000
s.seq_depth = 1000
println(s)

FacsScreen <: ScreenSetup

    Number of genes: 250
    Number of guides per gene: 5 (1250 guides total)
    Cells per guide at transfection: 1000 (1250000 cells total)
    Multiplicity of infection (M.O.I.): 0.25
    Number of cells per guide at sequencing: 1000 (1250000 cells total)

    Number of cells per guide sorted: 1000 (1250000 cells total)
    Gaussian standard deviation of sorting: 1.0 (phenotype units)
    Bins:
        bin1: 0-33 percentile of cells
        bin2: 67-100 percentile of cells

Construction of true phenotype distribution

Next, lets make our distribution of true phenotypes. The basic layout is a Dict mapping a class name to a tuple of the probability of selecting this class and then the Distributions.Sampleable from which to draw a random phenotype from this class. The probabilities across all the classes should add up to 1.

For example, here we are making three different classes of "genes": the first group are :inactive, i.e. they have no phenotype, so we'll set their phenotypes to 0.0 using a Crispulator.Delta. We'll also make them 60% of all the genes. The second group are the negative controls :negcontrol (the only required group) which make up 10% of the population of genes and also have no effect. The final group is :increasing which makes up 30% of all genes and which are represented by a Normal(μ=0.1, σ=0.1) distribution clamped between 0.025 and 1.

max_phenotype_dists = Dict{Symbol, Tuple{Float64, Sampleable}}(
    :inactive => (0.60, Delta(0.0)),
    :negcontrol => (0.1, Delta(0.0)),
    :increasing => (0.3, truncated(Normal(0.1, 0.1), 0.025, 1)),
);

Dict{Symbol, Tuple{Float64, Distributions.Sampleable}} with 3 entries:
  :negcontrol => (0.1, Delta(0.0))
  :inactive   => (0.6, Delta(0.0))
  :increasing => (0.3, Truncated(Distributions.Normal{Float64}(μ=0.1, σ=0.1); l…

Library construction

Now, we actually build the library. Here we're making a Crispulator.CRISPRi library and then getting the guides that were built from the true phenotype distribution that we constructed above and we also get the frequency of each guide in the library.

lib = Library(max_phenotype_dists, CRISPRi())
guides, guide_freqs_dist = construct_library(s, lib);

(Crispulator.Barcode[Crispulator.Barcode(1, 0.9616114720046925, 0.0, NaN, :linear, :inactive, -Inf), Crispulator.Barcode(1, 0.8611619766679292, 0.0, NaN, :linear, :inactive, -Inf), Crispulator.Barcode(1, 0.980025404130932, 0.0, NaN, :linear, :inactive, -Inf), Crispulator.Barcode(1, 0.017553584799220652, 0.0, NaN, :linear, :inactive, -Inf), Crispulator.Barcode(1, 0.8686462460188049, 0.0, NaN, :linear, :inactive, -Inf), Crispulator.Barcode(2, 0.9441742606374925, 0.0, NaN, :sigmoidal, :negcontrol, -Inf), Crispulator.Barcode(2, 0.9797763321607692, 0.0, NaN, :sigmoidal, :negcontrol, -Inf), Crispulator.Barcode(2, 0.8835463271309165, 0.0, NaN, :sigmoidal, :negcontrol, -Inf), Crispulator.Barcode(2, 0.799993820425561, 0.0, NaN, :sigmoidal, :negcontrol, -Inf), Crispulator.Barcode(2, 0.9568031825832851, 0.0, NaN, :sigmoidal, :negcontrol, -Inf)  …  Crispulator.Barcode(249, 0.906539997807153, 0.0, NaN, :sigmoidal, :inactive, -Inf), Crispulator.Barcode(249, 0.850881733768551, 0.0, NaN, :sigmoidal, :inactive, -Inf), Crispulator.Barcode(249, 0.8605847395470165, 0.0, NaN, :sigmoidal, :inactive, -Inf), Crispulator.Barcode(249, 0.7910623322067712, 0.0, NaN, :sigmoidal, :inactive, -Inf), Crispulator.Barcode(249, 0.8079005191480618, 0.0, NaN, :sigmoidal, :inactive, -Inf), Crispulator.Barcode(250, 0.9529320211807198, 0.0, NaN, :linear, :inactive, -Inf), Crispulator.Barcode(250, 0.773134135195202, 0.0, NaN, :linear, :inactive, -Inf), Crispulator.Barcode(250, 0.7233702709366947, 0.0, NaN, :linear, :inactive, -Inf), Crispulator.Barcode(250, 0.8244740201653049, 0.0, NaN, :linear, :inactive, -Inf), Crispulator.Barcode(250, 0.836069135080955, 0.0, NaN, :linear, :inactive, -Inf)], Distributions.Categorical{Float64, Vector{Float64}}(
support: Base.OneTo(1250)
p: [0.0007354014219856744, 0.0008406900650477474, 0.00023464568867706347, 0.0003402473209026797, 0.0005444154404624494, 0.0006141643424388771, 0.0008155608786020233, 0.0010961894561029232, 0.0014382312271859576, 0.001146884540473471  …  0.000282463019464141, 0.0009142861238055719, 0.0002921334389575369, 0.001212387324127321, 0.0001596148465530307, 0.0003156571159058512, 0.001090090879589099, 0.0005027666124330303, 0.00024817564790025434, 0.0003676946783592945]
)
)

Lets first look at what the true phenotype distribution of our different classes of guides looks like

df = DataFrame(Dict(
    :phenotype=>map(x->x.theo_phenotype, guides),
    :class=>map(x->x.class, guides),
    :freq=>pdf.(guide_freqs_dist, 1:(length(guides)))
))
plot(df, x=:phenotype, color=:class, Geom.histogram, Guide.ylabel("Number of guides"),
Guide.title("Guide phenotype distribution"))

As you can see, most guides should have a phenotype of 0. In FACS Screens this is equivalent to having no preference to being in either the left (bin1) or right (bin2) bins. The :increasing genes have a small preference to be in the right bin.

We can also look at the frequency of each guide in the library, which follows a Log-Normal distribution.

plot(df, x=:freq, color=:class, Geom.histogram(position=:stack),
    Guide.xlabel("Frequency"), Guide.ylabel("Number of guides"),
    Guide.title("Frequencies of guides in simulated library"))

Performing the screen

Now, we'll actually perform the screen. We'll first perform the transection via Crispulator.transfect, followed by the selection process via Crispulator.select:

cells, cell_phenotypes = transfect(s, lib, guides, guide_freqs_dist)
bin_cells = Crispulator.select(s, cells, cell_phenotypes, guides)
freqs = counts_to_freqs(bin_cells, length(guides));

Dict{Symbol, Vector{Float64}} with 2 entries:
  :bin1 => [0.000873138, 0.000729327, 0.000211608, 0.000355419, 0.000525937, 0.…
  :bin2 => [0.000788904, 0.00076836, 0.000172573, 0.000355418, 0.000427323, 0.0…

Lets look at what the observed phenotype distribution looks like when the selection was performed:

df = DataFrame(Dict(
    :phenotype=>map(x->x.theo_phenotype, guides),
    :class=>map(x->x.class, guides),
    :obs_freq=>map(x->x.obs_phenotype, guides)
))
plot(df, x=:obs_freq, Geom.density, Guide.xlabel("Observed phenotype on FACS machine"),
Guide.title("Kernel density estimate of guide observed phenotypes"), Guide.ylabel("ρ"))